100 REM  DOUG GERMAN DES MOINES IOWA 50315
110 CALL CLEAR
120 DISPLAY AT(12,11):"CHICKEN"
130 PRINT "WRITTEN BY D. GERMAN": :"3/82"
140 BIRDS=11
150 DIM V(11)
160 REM
170 REM  DEFINE SHAPES
180 REM
190 CALL MAGNIFY(2)
200 CALL CHAR(96,"FF") :: CALL COLOR(9,16,1)
210 CALL CHAR(97,"06045CBC3C589018")
220 CALL CHAR(98,"6666333333336666")
230 CALL CHAR(99,"6666CCCCCCCC6666")
240 CALL CHAR(100,"896A3EFD3C7FAAA9")
250 FOR I=1 TO 200 :: NEXT I
260 CALL CLEAR :: PRINT "DO YOU WANT THE RULES?": :"(Y OR N)"
270 CALL KEY(0,KEY,STATUS) :: IF STATUS=0 THEN 270 :: IF KEY=78 THEN 290 :: IF KEY<>89 THEN 270 :: GOSUB 940
280 GOSUB 810
290 GOSUB 1090
300 CALL CLEAR :: FOR I=1 TO 8 :: CALL COLOR(I,8,1) :: NEXT I
310 CALL CLEAR :: CALL SCREEN(2)
320 REM
330 REM     SET UP HIGHWAY
340 REM
350 CALL HCHAR(4,1,96,32) :: CALL HCHAR(13,1,96,32) :: CALL HCHAR(22,1,96,32)
360 FOR ROW=7 TO 19 STEP 3
370 FOR COL=1 TO 32 STEP 2
380 CALL HCHAR(ROW,COL,96)
390 NEXT COL
400 NEXT ROW
410 REM
420 REM     START TRAFFIC
430 REM
440 FOR I=1 TO 12
450 READ C,DROW,S
460 CALL SPRITE(#I,S,C,DROW,1,0,V(I-1))
470 NEXT I
480 REM
490 REM     START CHICKEN
500 REM
510 CALL SPRITE(#13,97,12,172,120)
520 REM
530 BIRDS=BIRDS-1 :: IF BIRDS=0 THEN 630 :: DISPLAY AT(24,1):"CHICKENS: "&STR$(BIRDS)
540 CALL COINC(ALL ,C) :: IF C=-1 THEN 590 :: CALL JOYST(1,X,Y) :: CALL MOTION(#13,-3.5*Y,3.5*X)
550 CALL POSITION(#13,Y,X) :: IF Y<16 THEN 560 :: GOTO 540
560 CALL MOTION(#13,0,0) :: DISPLAY AT(1,3)BEEP :"SAFE!" :: FOR I=1 TO 200 :: NEXT I :: DISPLAY AT(1,3):""
570 CALL LOCATE(#13,172,120) :: SAFE=SAFE+1
580 GOTO 530
590 CALL MOTION(#13,0,0) :: CALL PATTERN(#13,100) :: CALL COLOR(#13,7)
600 CALL SOUND(800,110,2) :: DISPLAY AT(1,3):"SQUISH!" :: FOR I=1 TO 200 :: NEXT I :: DISPLAY AT(1,3):""
610 CALL COLOR(#13,11) :: CALL PATTERN(#13,97) :: CALL LOCATE(#13,172,120)
620 GOTO 530
630 REM
640 REM    END ROUTINE
650 REM
660 CALL DELSPRITE(ALL) :: CALL CLEAR :: CALL SCREEN(8)
670 FOR I=1 TO 8 :: CALL COLOR(I,2,1) :: NEXT I
680 IF 10-SAFE<>1 THEN 700
690 PRINT "YOU KILLED 1 CHICKEN." :: GOTO 730
700 PRINT "YOU KILLED";10-SAFE;"CHICKENS."
710 IF SAFE<10 THEN 730
720 PRINT : :"COLONEL SANDERS HAS": :"DECIDED TO GO INTO THE": :"PIZZA BUSINESS!" :: GOTO 740
730 PRINT : :"YOU FOWL MURDERER!"
740 FOR I=1 TO 200 :: NEXT I
750 PRINT : :"CARE TO TRY AGAIN? (Y OR N)"
760 CALL KEY(0,KEY,STATUS) :: IF STATUS=0 THEN 760 :: IF KEY=78 THEN 790 :: IF KEY<>89 THEN 760
770 RESTORE :: SAFE=0 :: BIRDS=11 :: GOSUB 1090
780 GOTO 300
790 PRINT : :"CHICKEN!" :: FOR I=1 TO 200 :: NEXT I
800 END
810 REM
820 REM    RULES
830 REM
840 CALL CLEAR :: CALL SCREEN(15)
850 CALL SPRITE(#1,97,11,66,120) :: CALL SPRITE(#2,98,9,88,120)
860 DISPLAY AT(10,17):"CHICKEN"
870 DISPLAY AT(12,17):"CAR"
880 FOR I=1 TO 500 :: NEXT I
890 CALL DELSPRITE(ALL) :: CALL CLEAR
900 PRINT "USE JOYSTICK #1 TO": :"MANUVER YOUR INTREPID FOWL": :"ACROSS THE HIGHWAY."
910 PRINT : :"YOU HAVE 10 CHICKENS.": :"GOOD CLUCK!"
920 FOR I=1 TO 1000 :: NEXT I
930 RETURN
940 REM
950 REM     NARRATIVE
960 REM
970 CALL CLEAR
980 PRINT "THROUGHOUT HISTORY CERTAIN": :"QUESTIONS HAVE PUZZLED THE": :"GREATEST OF HUMAN MINDS."
990 PRINT : :"QUESTIONS SUCH AS:"
1000 PRINT : :"WHAT IS TRUTH?": :"WHAT IS THE NATURE OF THE   UNIVERSE?": :"AND"
1010 PRINT : :"WHY DID THE CHICKEN CROSS   THE ROAD?"
1020 FOR I=1 TO 1000 :: NEXT I
1030 PRINT : : :"GIVE UP? (PRESS ANY KEY)"
1040 CALL KEY(0,KEY,STATUS) :: IF STATUS=0 THEN 1040
1050 PRINT : :"TO SEE HIS FRIEND           GREGORY PECK!"
1060 FOR I=1 TO 400 :: NEXT I
1070 PRINT : :"HA! HA! HA!"
1080 FOR I=1 TO 200 :: NEXT I :: RETURN
1090 REM    DIFFICULTY
1100 CALL CLEAR
1110 PRINT "DIFFICULTY:":TAB(5);"1. VERY CHICKEN":TAB(5);"2. CHICKEN":TAB(5);"3. LOONEY!": :"YOUR CHOICE?"
1120 CALL KEY(0,KEY,STATUS) :: IF STATUS=0 THEN 1120 :: IF KEY<49 OR KEY>51 THEN 1120
1130 CALL CLEAR :: ON KEY-48 GOSUB 1150,1160,1170
1140 RETURN
1150 RESTORE 1240 :: GOTO 1180
1160 RESTORE 1230 :: GOTO 1180
1170 RESTORE 1250
1180 FOR I=0 TO 11 :: READ V(I) :: NEXT I
1190 RESTORE 1210
1200 RETURN
1210 DATA 5,30,99,9,54,99,3,78,99,14,102,98,8,126,98,13,150,98
1220 DATA 10,30,99,4,54,99,6,78,99,5,102,98,9,126,98,5,150,98
1230 DATA -20,-15,-25,20,25,15,-20,-15,-25,20,25,15
1240 DATA -15,-10,-20,15,20,10,-15,-10,-20,15,20,10
1250 DATA -25,-20,-30,25,30,20,-25,-20,-30,25,30,20
